Murrey Math Extremes Comparator

//@version=2
//Created by morpheus747
//code adapted from ucsgears user murrey math oscillator

// HOW IT WORKS
// Creates two murrey math oscillators (hidden) one with 256 length another with 32 length and compare each other.

// WHAT GIVE ME THIS SCRIPT
// The script can give you very valuable information:
// - Main Trend
// - Pullbacks detections
// - Extreme overbought oversold prices alerts
// - Divergences

// REFERENCES OF USAGE
// Main Trend Indications
// ****The main trend is indicated with green(bull) or red(bears) small "triangles" on the bottom(bull) or the top(bears) of the chart.
// *****To detect the Bull/Bear major trend the script use 256 murrey, if > 0 (green) we are uptrend in other cases we are downtrend

// Pullback detection
// ****The pullbacks are indicated with Green(bull) or red(bears) medium "Arrows"
// *****To detect pullbacks the system compare the long term murrey with the short term murrey, if long term is Green(green triangles)
// *****so we are in a main bull trend, if the short term murrey make an extreme low then the pullback is indicated
// *****The same for the short pullback, if long term murrey is RED and we have an extreme green short term murrey we shot a red arrow

// Extreme Overbught/Oversold
// ****The extreme OO is indicated with fancy diamonds
// *****To detect the Extremes price movements we combine the two murrey, if Long Term Murrey is overbought and short term murrey too
// *****Then the diamond show on the screen obove or below based on the extreme if overbought or oversold


// Resume
// Triangles indicate Major Trend Up/Down
// Arrows Indicate Continuation pullbacks
// Diamonds Indicate Extreme Prices


study(title="Murrey Math Extremes Comparator", shorttitle="Murrey_Ext_cmp", overlay=true, precision = 2)

// Inputs
length1 = input(256, minval = 10, title = "Look back Length 1 (suggested 256)")
length2 = input(32, minval = 10, title = "Look back Length 2 (suggested 32)")
mult = input(0.125, title = "Mutiplier; Only Supports 0.125 = 1/8")


// Donchanin Channel
hi1 = highest(high, length1)
hi2 = highest(high, length2)
lo1 = lowest(low, length1)
lo2 = lowest(low, length2)
range1 = hi1 - lo1
range2 = hi2 - lo2
multiplier1 = (range1) * mult
multiplier2 = (range2) * mult

midline1 = lo1 + multiplier1 * 4
midline2 = lo2 + multiplier2 * 4



oscillator1 = (close - midline1)/(range1/2)
oscillator2 = (close - midline2)/(range2/2)

//Plot the Main Trend
//trend up 256 murrey math (green)
plotshape(oscillator1>0?true:na,style=shape.triangleup,location=location.bottom,color=green)
//trend down 256 murrey math (red)
plotshape(oscillator1<0?true:na,style=shape.triangledown,location=location.top,color=red)

//Pullback detection system (divergence between 256 murrey and 32 murrey)
//bulls pullback detection
plotshape(oscillator1>0 and oscillator2<-0.75,style=shape.arrowup,color=green,location=location.belowbar,size=size.large)
//bears pullback detection
plotshape(oscillator1<0 and oscillator2>0.75,style=shape.arrowdown,color=red,location=location.abovebar,size=size.large)

//DANGERS ALERTS!
//this plots are alerts of hyper extremes prices!
//Hyper bulls indication for imminent reverse to sell
plotshape(oscillator1>0.90 and oscillator2>0.90,style=shape.diamond,color=purple,location=location.abovebar,size=size.small)
//Hyper bears indication for imminent reverse to buy
plotshape(oscillator1<-0.90 and oscillator2<-0.90,style=shape.diamond,color=fuchsia,location=location.belowbar,size=size.small)